34 lines
1.3 KiB
Gnuplot
Executable File
34 lines
1.3 KiB
Gnuplot
Executable File
set terminal epslatex font 8 color dashed
|
|
set output './ModeleLaTeX_TP-gnuplottex-fig17.tex'
|
|
set format '\num{%g}'
|
|
set key top right Left
|
|
set key width 1
|
|
set key heigh 1
|
|
set key spacing 1.5
|
|
|
|
set xlabel 'Temps t (\si{\second})' # attention il faut parfois utiliser certains guillemets
|
|
# notamment quand on utilise la commande \si, il faut impérativement des primes '...'
|
|
set ylabel 'Tension U (\si{\volt})'
|
|
|
|
R = 9.94e6
|
|
# Création du fit des données
|
|
# ---
|
|
# la fonction de fit
|
|
f(x)=(9.040-b)*exp(-(x-7.309)/a)+b
|
|
fit f(x) 'condo/data_condo_2_0.15µF_9.94MΩ.txt' index 0 u 1:2 via a,b
|
|
C=a/R*1000000
|
|
e=(0.15-C)/0.15*100
|
|
title_f(a,b) = sprintf('\(\tau = RC = \SI{%.3f}{\second}\) ; \(C = \SI{%.3f}{\micro\farad}\) ; {%.1f}\%', a, C, e)
|
|
|
|
# Pour Gnuplot directement en ligne de commande
|
|
#plot [0.55:5][0:4] 'data_condo.txt' index 0 u 1:2
|
|
|
|
set style line 1 lt 0 lw 4
|
|
|
|
plot [7.3:7.4][0:9.1]\
|
|
9.040*exp(-(x-7.309)/(R*0.15e-6*1.2)) w filledc y1=0 fc rgb 'grey90' title '',\
|
|
9.040*exp(-(x-7.309)/(R*0.15e-6*0.8)) w filledc y1=0 fc 'white' title '',\
|
|
9.040*exp(-(x-7.309)/(R*0.15e-6)) ls 1 title '\(U(t)=9.184\cdot e^{-(t-5.296)/0,0446}\) ; i(C)=20\%',\
|
|
'condo/data_condo_2_0.15µF_9.94MΩ.txt' index 0 u 1:2:5:4 title '\(R=\SI{9.94}{\mega\ohm}\) ; \(C=\SI{0.15}{}\pm\SI{0.03}{\micro\farad}\)' pt 4 lc rgb 'blue' w xyerrorbars,\
|
|
f(x) title title_f(a,b) lc 'green'
|