set terminal epslatex font 8 color dashed
set output './ModeleLaTeX_TP-gnuplottex-fig14.tex'
set format '\num{%g}'
set key top right Right
set key width 1
set key heigh 1
set key spacing 1.5

set xlabel 'Temps t (\si{\second})' # attention il faut parfois utiliser certains guillemets
# notamment quand on utilise la commande \si, il faut impérativement des primes '...'
set ylabel 'Tension U (\si{\volt})'

R = 455
# Création du fit des données
# ---
# la fonction de fit
f(x)=(9.596)*exp(-(x-14.013)/a)
fit f(x) 'condo/data_condo_multiΩ_100µF.txt' index 0 u 1:2 via a
C=a/R*1000000
e=(100-C)/100*100
title_f(a,b) = sprintf('\SI{455}{\ohm}→\(C = \SI{%.3f}{\micro\farad}\) ; {%.1f}\%', C, e)

# Pour Gnuplot directement en ligne de commande
#plot [0.55:5][0:4] 'data_condo.txt' index 0 u 1:2

set style line 1 lt 0 lw 4

plot [0:0.8][0:9.6]\
9.596*exp(-(x)/(R*100e-6*1.2)) w filledc y1=0 fc rgb 'grey90' title '',\
9.596*exp(-(x)/(R*100e-6*0.8)) w filledc y1=0 fc 'white' title '',\
9.596*exp(-(x)/(R*100e-6)) ls 1 title title_f(a,b),\
'condo/data_condo_multiΩ_100µF.txt' index 1 u ($1-5.592):2:5:4 title '\(R=\SI{1130}{\ohm}\)' pt 4 w xyerrorbars,\
'condo/data_condo_multiΩ_100µF.txt' index 2 u ($1-3.847):2:5:4 title '\(\SI{800}{\ohm}\)' pt 4 w xyerrorbars,\
'condo/data_condo_multiΩ_100µF.txt' index 3 u ($1-5.618):2:5:4 title '\(\SI{600}{\ohm}\)' pt 4 w xyerrorbars,\
'condo/data_condo_multiΩ_100µF.txt' index 0 u ($1-14.013):2:5:4 title '\(\SI{455}{\ohm}\)' pt 4 lc rgb 'blue' w xyerrorbars,\
'condo/data_condo_multiΩ_100µF.txt' index 4 u ($1-5.114):2:5:4 title '\(\SI{400}{\ohm}\)' pt 4 w xyerrorbars,\
'condo/data_condo_multiΩ_100µF.txt' index 5 u ($1-5.298):2:5:4 title '\(\SI{200}{\ohm}\)' pt 4 w xyerrorbars,\
'condo/data_condo_multiΩ_100µF.txt' index 6 u ($1-4.158):2:5:4 title '\(\SI{100}{\ohm}\)' pt 4 w xyerrorbars#,\
f(x) title title_f(a,b) lc 'green'